Kofi / Illestpreacha
Code is Poetry & Data is Poetry

Code is Poetry & Data is Poetry

WCCChallenge: Spirals

WCCChallenge: Spirals

Spiraling Orbit

Kofi / Illestpreacha's photo
Kofi / Illestpreacha
·Aug 20, 2022·

3 min read

For this week's challenge : Spirals, I decided to bring back LiveCodeLab for an Audiovisual coded narrative of spirals named

Spiraling Orbit

I wanted the movements to not only represent a spiral in shape but also depict, spiraling upwards and downwards . This was achievable through using the sin/cos/tan functions , wave function and time with modulo function.

The audio added is to maintain the feeling of this orbit being in a constant spiral. This constant sound allows the spiraling effect to not only be heard and seen but also be sense in a state of “distress”

To play with the code, copy and paste it and then put it in the Livecodelab's site to see how the code functions.

As commonly seen in these WCCChallenge submissions by me, this post will contain a video, poem and the code to the submitted piece.


Poem

Spiraling as the noise bounces
Bounces to the left
Bounces to the right
With no regard of the concept of depth
The concept of pace
Just knowing sometimes the colours or bright
And other times it needs to be dimmed
Needed to be simmed
With the spillover needing to be trimmed
To the continue with the rest of the steps
The rest of breaths
Ready, willing to pounce

Video


Code


/*this block of code changes the bpm, the number 
of elements per scene and the adjustable size*/

if time % 30 > 20
    bpm 80 
    num = 400
    reSize = 0.2
else if time % 30 < 20 && time % 30 > 10
    bpm 40
    num = 500
    reSize = -0.2
else
    bpm 20
    num = 600
    reSize = 0.05

// musical elements 
play 'tranceKick'  ,'-x-x ---x x-x- x-xx'
play "alienBeep" + int(random 16) ,'x-x'
play "glass" + int(random 9) ,'x-ox--x'
play "cosmos"  ,'--x- -x-x --x- -x-xx'
play "hiss" + int(random 3) ,'x'
play "hoover" + int(random 4) ,'x-ox'

/*This block of code control the movement and background */

if time % 22 > 12
    scale ((sin(time % 6) + 0.5)/8) + 0.12
    simpleGradient red,orange,pink
else if time % 22 < 12 && time % 22 > 5
    scale ((sin(time % 9) + 0.5)/19) + 0.12
    simpleGradient teal,yellow,orange
else
    scale ((sin(time % 12) + 0.5)/27) + 0.19
    simpleGradient pink,aqua,red


rotate time
scale 0.7 + reSize

if time % 20 < 6
    animationStyle motionBlur
else if time % 20 > 13
    animationStyle paintOver

num times with i
    fill red
    stroke blue
    rotate time * 2 + sin(i), time * 3 - cos(i), time * 2 + tan(i)/(frame/100)
        move cos(time / 10), tan(wave(0.03)), sin(time % 10)
            rect 1 - cos(time), tan(wave(0.04)), tan(time * (wave(0.03)))

num times with i
    fill blue
    stroke black
    rotate time * 1.5 + sin(i), time * 1.2 - cos(i), time * 1.3 + tan(i)/(frame/100)
        move cos(time / 10)+ 10 - time%6, tan(wave(0.03)), sin(time % 10)
            rect 1 - cos(time), tan(wave(0.04)), tan(time * (wave(0.03)))

num times with i

    if time % 24 > 12
        fill white
        stroke green
    else
        fill gold
        stroke black

    rotate time * 3 - cos(i), time * 2 + tan(i)/(frame/100),time * 2 + sin(i)
        move cos(time / 10), tan(wave(0.03)), sin(time % 10)
            rect 1 - cos(time), tan(wave(0.04)), tan(time * (wave(0.03)))
 
Share this